При формировании пользовательского интерфейса прикладной задачи довольно часто возникают ситуации, когда для удобства работы пользователя необходимо дать ему возможность выбирать какое-либо значение из заранее подготовленного списка. Возможности работы со справочниками, журналами и перечислениями предоставляют достаточно мощные средства выбора этих объектов. Однако, существует также необходимость в выборе значений из списков, сформированных и отсортированных нестандартным образом, которые невозможно или неудобно получать непосредственно при работе со стандартными визуальными представлениями журналов, справочников или перечислений. Для этого в системе «1С:Предприятие» версии 7.7 используется специальный агрегатный тип данных — "СписокЗначений", а также специальные элементы форм диалога — «Список» и «Поле со списком».
Объект типа "СписокЗначений" — это средство языка (не сохраняемый в БД объект), которое позволяет строить «динамические массивы» и манипулировать ими (добавлять, редактировать, удалять элементы, сортировать). Список значений может быть наполнен значениями любого типа, то есть в одном списке типы хранимых значений могут быть разными. Одним из примеров использования данного объекта может служить организация выбора конкретного документа из списка возможных документов, сформированного по сложному алгоритму.
Замечу, что для списков значений допустим так называемый «множественный выбор», то есть одновременный выбор нескольких значений списка. С помощью механизма пометок пользователь может выделить не одно, а сразу все интересующие его значения.
Для организации множественного выбора значений можно, например, использовать такой элемент формы, как «Список», установив в свойствах этого элемента на вкладке «Дополнительно» опцию «Список с пометками». Организовать же множественный выбор из виртуального списка позволяет метод ОтметитьЗначения(), о котором мы поговорим далее.
Контекст работы с объектом
Во всех программных модулях вызов методов для работы со списками значений может выполняться при помощи переменной со ссылкой на объект типа "СписокЗначений". Такие объекты можно создавать при помощи функции СоздатьОбъект(), а чтобы вызвать метод объекта, имя метода (с указанием необходимых параметров) записывается через точку после идентификатора переменной. Кроме того, если в форму диалога при помощи визуальных средств Конфигуратора вставлены специальные элементы форм диалога «Список» и «Поле со списком», то идентификаторы этих элементов доступны в контексте программного модуля этой формы как уже существующие объекты типа "СписокЗначений".
При создании объекта типа "СписокЗначений" с помощью функции СоздатьОбъект() в качестве названия агрегатного типа данных обязательно должно выступать ключевое слово «СписокЗначений» (англоязычный синоним — «ValueList»), например:
МойСписок = СоздатьОбъект("СписокЗначений");
или
MyList = CreateObject("ValueList");
Элементы форм для работы со списками
Элемент «Список»
Разместить в диалоговой форме элемент «Список» можно при помощи визуальных средств Конфигуратора, щёлкнув по кнопке «Список» на панели редактирования форм (см. рис. ниже, справа) или выбрав в главном меню пункты «Вставить −> Список» (см. рис. ниже, слева).
После размещения элемента «Список» в форме на экран будет выведено окно редактирования свойств элемента (см. рис. ниже), где на вкладке «Общие» следует указать идентификатор списка. Этот идентификатор будет доступен в контексте программного модуля данной формы как уже существующий объект типа "СписокЗначений".
На вкладке «Дополнительно» в поле «Формула» можно записать выражение, например, вызов соответствующей процедуры, которая будет выполняться при нажатии клавиши Enter, когда фокус находится на данном элементе диалоговой формы (то есть когда элемент активен). На этой же вкладке можно указать, что список будет иметь поле для пометок (для выделения сразу нескольких значений списка). А установив опцию «Пропускать при вводе», мы можем удалить список из порядка обхода (то есть при обходе с помощью клавиши Tab или комбинации клавиш Shift+Tab он будет пропускаться).
На вкладке «Описание» (см. рис. ниже) можно задать текст для всплывающей подсказки, которая будет появляться при наведении указателя мыши на список.
Элемент «Поле со списком»
Разместить в диалоговой форме элемент «Поле со списком» можно при помощи визуальных средств Конфигуратора, щёлкнув по кнопке «Поле со списком» в панели редактирования форм (см. рис. ниже, справа) или выбрав в главном меню пункты «Вставить −> Поле со списком» (см. рис. ниже, слева).
После размещения элемента «Поле со списком» в форме на экран будет выведено окно редактирования свойств элемента (см. рис. ниже), где на вкладке «Общие» следует указать идентификатор списка. Этот идентификатор будет доступен в контексте программного модуля данной формы как уже существующий объект типа "СписокЗначений".
На вкладке «Дополнительно» в поле «Формула» можно записать выражение, например, вызов соответствующей процедуры, которая будет выполняться при нажатии клавиши Enter, когда фокус находится на данном элементе диалоговой формы (то есть когда элемент активен). Установив опцию «Пропускать при вводе», мы можем удалить список из порядка обхода (то есть при обходе с помощью клавиши Tab или комбинации клавиш Shift+Tab он будет пропускаться).
На вкладке «Описание» можно задать текст для всплывающей подсказки, которая будет появляться при наведении указателя мыши на список.
Методы объекта «СписокЗначений»
Формирование и изменение списка значений
Добавить новое значение в конец списка позволяет метод ДобавитьЗначение(). Англоязычный синоним имени метода — AddValue().
Синтаксис метода:
ДобавитьЗначение(<Значение>, <Представление>)
где
- <Значение> — выражение, содержащее значение, добавляемое в список;
- <Представление> — строковое выражение, содержащее символьное (визуальное) представление добавляемого значения. По умолчанию принимает стандартное в системе «1С:Предприятие» символьное представление объекта, указанного в первом параметре. Представление используется в дальнейшем для удобства сортировки и выбора значений из списка (отображается в диалоговом окне выбора). Параметр является необязательным.
Пример использования:
ПолеСоСписком.ДобавитьЗначение(ВидРасчета.ДоплатаПроцентом, "Процентом"); ПолеСоСписком.ДобавитьЗначение(ВидРасчета.ДоплатаСуммой, "Суммой");
Визуально это будет выглядеть так:
Добавить значение в указанную позицию списка позволяет метод ВставитьЗначение(). Англоязычный синоним имени метода — InsertValue().
Синтаксис метода:
ВставитьЗначение(<Позиция>, <Значение>, <Представление>, <КоличРаз>)
где
- <Позиция> — числовое выражение, дающее номером позиции в списке, начиная с которого будут вставлены новые значения. Номер позиции может быть от 1 до
РазмерСписка() + 1; - <Значение> — выражение, содержащее значение, добавляемое в список;
- <Представление> — строковое выражение, содержащее символьное (визуальное) представление добавляемого значения. По умолчанию принимает стандартное в системе «1С:Предприятие» символьное представление объекта, указанного во втором параметре;
- <КоличРаз> — числовое выражение, дающее число — количество вставляемых значений. Параметр является необязательным. Значение по умолчанию — 1.
Пример использования:
МойСписок = СоздатьОбъект("СписокЗначений"); МойСписок.ВставитьЗначение(1, ВидРасчета.ДоплатаПроцентом, "Процентом"); МойСписок.ВставитьЗначение(2, ВидРасчета.ДоплатаСуммой, "Суммой");
Установить в списке значение с указанным представлением позволяет метод Установить() (англоязычный синоним — Set()). Если значение с таким представлением уже есть, то изменяется значение, если нет, то значение с указанным представлением добавляется в конец списка.
Синтаксис метода:
Установить(<Представление>, <Значение>)
где
- <Представление> — строковое выражение, содержащее символьное (визуальное) представление устанавливаемого значения;
- <Значение> — выражение, содержащее устанавливаемое значение.
Пример использования:
МойСписок.Установить("Процентом", ВидРасчета.ДоплатаПроцентом);
Установить значения элементов списка, начиная с указанной позиции списка позволяет метод УстановитьЗначение(). Англоязычный синоним имени метода — SetValue().
Синтаксис метода:
УстановитьЗначение(<Позиция>, <Значение>, <Представление>, <КоличРаз>)
где
- <Позиция> — числовое выражение, дающее номер позиции в списке, начиная с которого будут устанавливаться новые значения. Номер позиции может быть от 1 до
РазмерСписка() + 1; - <Значение> — выражение, содержащее устанавливаемое значение;
- <Представление> — строковое выражение, содержащее символьное (визуальное) представление устанавливаемого значения. По умолчанию принимает стандартное в системе «1С:Предприятие» символьное представление объекта, указанного во втором параметре;
- <КоличРаз> — числовое выражение, дающее число — количество устанавливаемых значений. Параметр является необязательным. Значение по умолчанию — 1.
Пример использования:
МойСписок.УстановитьЗначение(1, ВидРасчета.ДоплатаПроцентом, "Процентом");
Переместить указанное значение списка на новую позицию позволяет метода СдвинутьЗначение(). Англоязычный синоним имени метода — MoveValue().
Синтаксис метода:
СдвинутьЗначение(<Количество>, <Позиция>)
где
- <Количество> — числовое выражение, задающее количество позиций, на которое надо переместить значение. Если число положительное, то значение сдвигается вниз, если отрицательное, то вверх;
- <Позиция> — числовое выражение, задающее номер позиции, значение которой надо переместить.
Пример использования:
МойСписок.СдвинутьЗначение(1, Поз);
Выполнить сортировку списка по значениям позволяет метод Сортировать() (англоязычный синоним — Sort()). Если первый элемент списка (значение в первой позиции) имеет базовый тип данных (число, строка, дата), то сортировка производится по значениям элементов, приведённых стандартными правилами к типу первого элемента. В противном случае, если первый элемент имеет агрегатный тип данных, сортировка производится по значениям элементов, приведенных к строковому представлению типа данных.
Синтаксис метода:
Сортировать(<Направление>, <ДокументыПоДате>)
где
- <Направление> — числовое выражение. Если результат — 0, то сортировка будет осуществляться по возрастанию. Если не 0 то сортировка будет осуществляться по убыванию. Параметр является необязательным. Значение по умолчанию — 0;
- <ДокументыПоДате> — необязательный параметр, который имеет смысл только в том случае, если значениями списка являются документы. В этом случае можно задавать сортировку документов по их хронологии. Число: 1 — сортировка по хронологии документов; 0 — нет. Значение по умолчанию — 0.
Пример использования:
МойСписок = СоздатьОбъект("СписокЗначений"); МойСписок.ВставитьЗначение(1, ВидРасчета.ДоплатаПроцентом, "Процентом"); МойСписок.ВставитьЗначение(2, ВидРасчета.ДоплатаСуммой, "Суммой"); МойСписок.Сортировать();
Выполнить сортировку списка по символьному представлению в соответствии с порядком, заданным в параметре, позволяет метод СортироватьПоПредставлению(). Англоязычный синоним имени метода — SortByPresent().
Синтаксис метода:
СортироватьПоПредставлению(<Направление>)
где <Направление> — числовое выражение. Если результат равен нулю, то сортировка будет осуществляться по возрастанию. Если не 0 то сортировка будет осуществляться по убыванию. Параметр является необязательным. Значение по умолчанию — 0.
Пример использования:
МойСписок = СоздатьОбъект("СписокЗначений"); МойСписок.ВставитьЗначение(1, ВидРасчета.ДоплатаПроцентом, "Процентом"); МойСписок.ВставитьЗначение(2, ВидРасчета.ДоплатаСуммой, "Суммой"); МойСписок.СортироватьПоПредставлению();
Удалить указанное количество значений, начиная с указанной позиции, позволяет метод УдалитьЗначение(). Англоязычный синоним имени метода — RemoveValue().
Синтаксис метода:
УдалитьЗначение(<Позиция>, <Количество>)
где
- <Позиция> — числовое выражение, задающее номер позиции в списке, начиная с которого будут удалены значения. Номер позиции может быть от 1 до количества элементов в списке;
- <Количество> — числовое выражение, задающее количество удаляемых значений. Параметр является необязательным. Значение по умолчанию — 1.
Пример использования:
МойСписок.УдалитьЗначение(1, 2);
Примечание: Если требуется отфильтровать таблицу или список значений, удаляя из них строки, не подходящие по условию, то следует руководствоваться двумя правилами:
- Удалять строки нужно от конца к началу списка.
- Помните, что удаление элемента работает гораздо медленнее, чем добавление. Поэтому быстрее будет создать новый список или таблицу с такой же структурой и в неё копировать оставляемые элементы.
Удалить все элементы списка позволяет метод УдалитьВсе() (англоязычный синоним — RemoveAll()). Параметры у данного метода отсутствуют.
Пример использования:
МойСписок.УдалитьВсе();
Поиск и выбор значений из списка
Определить общее количество элементов в списке позволяет метод РазмерСписка() (англоязычный синоним — GetListSize()). Параметров данный метод не имеет, а возвращаемым значением является число, показывающее количество элементов в списке.
Пример использования:
Разм = МойСписок.РазмерСписка();
Проверить вхождение заданного значения в список значений позволяет метод Принадлежит() (англоязычный синоним — Belong()). Метод возвращает число: 1 — если проверяемое значение входит в список значений; 0 — если не входит. Данный метод оптимизирует проверку принадлежности при массовых последовательных сравнениях, если между сравнениями сам список значений не меняется.
Примечание: Если на принадлежность проверяется значение типа элемент справочника, то проверка выполняется с учётом его возможного вхождения в группы справочников, которые являются значениями списка значений.
Синтаксис метода:
Принадлежит(<Значение>)
где <Значение> — выражение, содержащее значение, проверяемое на вхождение в список значений.
Пример использования:
Процедура ПроверитьКлиентов(СписокГруппКлиентов) // в качестве параметра Процедуры передается СписокЗначений // в котором записаны как элементы справочника Клиенты, так и // группы этого справочника Док = СоздатьОбъект("Документ.Накладная"); Док.ВыбратьДокументы(); Пока Док.ПолучитьДокумент() = 1 Цикл Если СписокГруппКлиентов.Принадлежит(Док.Клиент) = 1 Тогда Сообщить(Док.Клиент.Наименование + " " + Док); КонецЕсли; КонецЦикла; КонецПроцедуры
Определить номер позиции в списке для указанного значения позволяет метод НайтиЗначение() (англоязычный синоним — FindValue()). Если значение в списке отсутствует, метод вернёт 0.
Синтаксис метода:
НайтиЗначение(<Значение>)
где <Значение> — выражение, содержащее искомое значение.
Пример использования:
Позиция = МойСписок.НайтиЗначение(ВидРасчета.ДоплатаПроцентом);
Получить значение элемента, находящегося в указанной позиции списка позволяет метода ПолучитьЗначение() (англоязычный синоним — GetValue()). Возвращаемым значением метода будет искомое значение.
Синтаксис метода:
ПолучитьЗначение(<Позиция>, <Представление>)
где
- <Позиция> — числовое выражение, задающее номер позиции элемента в списке, значение которого будет возвращено. Номер позиции может быть от 1 до количества элементов в списке;
- <Представление> — идентификатор переменной, в которую будет возвращено символьное представление получаемого значения.
Пример использования:
ОпредПредст = ""; ОпредВид = Спис.ПолучитьЗначение(1, ОпредПредст);
Получить значение по указанному представлению позволяет метод Получить() (англоязычный синоним — Get()). Если значения с таким представлением нет, то метод возвращает пустое значение.
Синтаксис метода:
Получить(<Представление>)
где <Представление> — строковое выражение, содержащее символьное (визуальное) представление искомого значения.
Пример использования:
Знач = МойСписок.Получить("Процентом");
Вызвать диалоговое окно для интерактивного выбора значения из заранее подготовленного списка позволяет метод ВыбратьЗначение() (англоязычный синоним — ChooseValue()). Возвращаемым значением метода является число: 1 — если выбор произведён (нажата кнопка «ОК»); 0 — если выбор не произведён (нажата кнопка «Отмена»), −1 (минус единица) — если закончилось время ожидания отклика пользователя.
Примечание: Данный метод может использоваться только для объектов, созданных при помощи функции СоздатьОбъект().
Синтаксис метода:
ВыбратьЗначение(<Значение>, <3аголовок>, <Позиция>, <Таймаут>, <СпособВыбора>)
где
- <Значение> — идентификатор переменной, куда помещается выбранное значение. Перед вызовом метода переменной можно присвоить значение, которое будет использовано по умолчанию (на этом значении будет установлен курсор при открытии окна выбора);
- <3аголовок> — строковое выражение, значение которого отображается в заголовке диалогового окна и может использоваться для подсказки пользователю;
- <Позиция> — идентификатор переменной, куда помещается номер позиции выбранного значения в списке;
- <Таймаут> — числовое выражение, значение которого задаёт время ожидания системы (в секундах) на отклик пользователя. Параметр является необязательным. Если значение не задано, то время ожидания бесконечно;
- <СпособВыбора> — числовое выражение, значение которого задаёт способ выбора значения:
- 0 (значение по умолчанию) — в виде диалога;
- 1 — выбор производится в виде меню, которое подстраивается по месту текущего элемента диалога или ячейки таблицы, откуда вызвано;
- 2 — выбор маленьким списком (список похож на выбор значения перечисления), также привязанным к позиции элемента диалога.
Примечание: Если выбор отменён, то значение параметров не меняются.
Пример:
МойСписок = СоздатьОбъект("СписокЗначений"); МойСписок.ДобавитьЗначение(ВидРасчета.ДоплатаЛроцентом, "Процентом"); МойСписок.ДобавитьЗначение(ВидРасчета.ДоплатаСуммой, "Суммой"); МойСписок.ВыбратьЗначение(ВыбрЗнач, "Выберите значение", ВыбрПоз, 45, 0);
Результатом работы данного примера будет следующее окно:
При замене значения последнего параметра метода ВыбратьЗначение() на 1 и при вызове кода из кнопки результат будет следующим:
а при замене значения параметра на 2:
Пример создания меню выбора печатной формы под кнопкой «Печать»:
Процедура ВыборПечатнойФормы() Перем ВыбрПункт; СписокПечатныхФорм = СоздатьОбъект("СписокЗначений"); СписокПечатныхФорм.ДобавитьЗначение("Заявка в банк"); СписокПечатныхФорм.ДобавитьЗначение("Печать файла"); Если СписокПечатныхФорм.ВыбратьЗначение(ВыбрПункт,,,,1)=1 Тогда Если ВыбрПункт="Заявка в банк" Тогда // Вызываем процедуру печати заявки в банк ПечатьЗаявкиДляБанка(); Иначе // Вызываем процедуру печати содержимого файла ПечатьФайла(); КонецЕсли; КонецЕсли; КонецПроцедуры
Имя процедуры ВыборПечатнойФормы() из вышеприведённого примера должно быть указано в свойствах кнопки «Печать» (вкладка «Дополнительно», поле «Формула»).
Произвести пометку нескольких значений списка и таким образом организовать так называемый «множественный выбор» позволяет метод Пометка() (англоязычный синоним — Check()). Кроме того, этот метод позволяет выполнить и обратное действие — считать установленные пометки. Возвращаемым значением метода является число, характеризующее состояние пометки на момент, предшествующий вызову метода: 1 — пометка установлена; 0 — пометка отсутствует.
Синтаксис метода:
Пометка(<Позиция>, <ФлагПометки>)
где
- <Позиция> — числовое выражение, задающее номер позиции выбранного значения в списке;
- <ФлагПометки> — число, характеризующее выполняемое методом действие: 1 — установить пометку; 0 — снять пометку. Параметр является необязательным. Если данный параметр опущен, то пометка значения списка не изменяется.
Пример использования метода:
МойСписок = СоздатьОбъект("СписокЗначений"); МойСписок.ДобавитьЗначение(ВидРасчета.ДоплатаПроцентом, "Процентом"); МойСписок.ДобавитьЗначение(ВидРасчета.ДоплатаСуммой, "Суммой"); МойСписок.ОтметитьЗначения(ВыбрЗнач, "Выберите значение", ВыбрПоз, 45); // проверим состояние пометок Для Ном=1 По МойСписок.РазмерСписка() Цикл Если МойСписок.Пометка(Ном) = 1 Тогда // выполняем какие-то действия . . . КонецЕсли; КонецЦикла;
Вызвать диалоговое окно для интерактивного выбора значения из заранее подготовленного списка с пометками позволяет метод ОтметитьЗначения() (англоязычный синоним — CheckValues()). Данный метод может использоваться только для объектов типа "СписокЗначений", созданных с помощью функции СоздатьОбъект() (то есть для виртуальных списков с пометками). Возвращаемым значением метода является число: 1 — если выбор произведён (нажата кнопка «ОК»); 0 — если выбор не произведён (нажата кнопка «Отмена»), −1 (минус единица) — если закончилось время ожидания отклика пользователя.
Синтаксис метода:
ОтметитьЗначения(<Значение>, <3аголовок>, <Позиция>, <Таймаут>)
где
- <Значение> — идентификатор переменной, куда помещается значение, отмеченное курсором (обычно это последнее значение, на котором была установлена или снята пометка). Перед вызовом метода переменной можно присвоить значение, которое по умолчанию будет подсвечено курсором (при открытии окна выбора);
- <3аголовок> — строковое выражение, значение которого отображается в заголовке диалогового окна и может использоваться для подсказки пользователю;
- <Позиция> — идентификатор переменной, куда помещается номер позиции значения, отмеченного в списке курсором (обычно это последнее значение, на котором была установлена или снята пометка). Параметр является необязательным;
- <Таймаут> — числовое выражение, задающее время ожидания системы (в секундах) на отклик пользователя. Параметр является необязательным. Если значение не задано, то время ожидания бесконечно.
Примечание: Если в диалоговом окне пользователь не пометил ни одного значения и нажал кнопку «ОК», метод ОтметитьЗначения() сработает аналогично методу ВыбратьЗначение(). В переменную, указанную в первом параметре, вернётся значение, на котором стоял курсор, а в переменную, указанную в третьем параметре — позиция выделенного курсором значения. Если же выбор был отменён, то значение параметров не меняются.
Пример использования метода:
МойСписок = СоздатьОбъект("СписокЗначений"); МойСписок.ДобавитьЗначение(ВидРасчета.ДоплатаПроцентом, "Процентом"); МойСписок.ДобавитьЗначение(ВидРасчета.ДоплатаСуммой, "Суммой"); МойСписок.ОтметитьЗначения(ВыбрЗнач, "Выберите значение", ВыбрПоз, 45);
Результатом работы данного кода будет следующее окно:
Установить и/или считать текущее положение курсора в элементе диалога типа «Список» или «Поле со списком» позволяет метод ТекущаяСтрока() (англоязычный синоним — CurSel()). В тексте программного модуля данный метод можно использовать синтаксически как функцию или процедуру. Возвращаемым значением метода является числовое значение, соответствующее индексу текущей строки поля диалога до вызова метода.
Примечание: Данный метод можно использовать только для объектов, которые созданы при помощи визуальных средств Конфигуратора.
Синтаксис метода:
ТекущаяСтрока(<ИндексСтроки>)
где <ИндексСтроки> — числовое выражение, задающее индекс строки для элемента диалога типа «Список» или «Поле со списком», на которую требуется установить курсор. Параметр является необязательным. Если параметр не задан, то положение курсора в поле диалога не меняется.
Пример использования метода:
// получаем номер выбранной строки списка Поз = МойСписок.ТекущаяСтрока(); // устанавливаем текущую строку списка МойСписок.ТекущаяСтрока(3); // получаем номер выбранной строки списка // и устанавливаем новую позицию текущей строки ПозНов = 2; ПозСтар = МойСписок.ТекущаяСтрока(ПозНов);
Преобразование списка в строку или строки в список
Преобразовать список значений в строку позволяет метод ВСтрокуСРазделителями() (англоязычный синоним — ToSeparatedString()). Параметры у этого метода отсутствуют, а возвращаемое значение представляет собой строку, составленную из строк, заключённых в двойные кавычки, или чисел, разделённых запятыми.
Пример:
СтрЗнач = МойСписок.ВСтрокуСРазделителями();
Заполнить список значениями из переданной в качестве параметра строки, содержащей строки в двойных кавычках и числа, разделённые запятыми, позволяет метод ИзСтрокиСРазделителями(). Англоязычный синоним имени метода — FromSeparatedString().
Пример использования:
МойСписок.ИзСтрокиСРазделителями("5, 6, 12, 68, ""ОпредПредст""");
Как видно из вышеприведённого примера, строки, находящиеся внутри передаваемой строки выделяются удвоенными кавычками.
Выгрузка значений списков в другие списки или таблицы
Выгрузить список значений в другой список или таблицу значений позволяет метод Выгрузить() (англоязычный синоним — Unload()). При выгрузке в таблицу значений, в ней добавляется новая колонка для загружаемых значений.
Синтаксис метода:
Выгрузить(<Цель>, <НачПозиция>, <Количество>)
где
- <Цель> — переменная со ссылкой на объект типа
"ТаблицаЗначений"или"СписокЗначений", в который нужно выгрузить данные. Если переменная содержит пустое значение, система сама создаст объект типа"СписокЗначений"; - <НачПозиция> — номер начальной позиции, с которой надо начинать выгрузку. Параметр является необязательным. Значение по умолчанию 1;
- <Количество> — количество выгружаемых значений. Параметр является необязательным. Если не указан, то выгружаются все значения.
Пример:
МойСписок.Выгрузить(НовыйСписок);
Другие статьи по схожей тематике
